void sendMorseChar(byte letter)
{
  byte bp = 0;
  byte ditordah = 0;
  bool first = false;
  unsigned int j = 0;
  unsigned int ele_len = DOT_BLNK_LEN;
  
  switch (letter)
  {
    case ' ':
      delay(ele_len * 7);//there is a seven unit delay between words
      break;
 
    case 8:
    case 127:
      break;
 
    default:
    // while bp is not our end of table flag
      while (bp != 0xff)
      {
        // we should be pointing as an alpha/digit/puncutation character in our table
        bp = pgm_read_byte_near(morse_table + j);
 
        // have we reached the end of our table ?
        if (bp != 0xff)
        {
          // is the chacater we're pointing to in the Morse table the same as the
          // character we want to send ?
          if (bp == letter)
          {
            // yes - so bump our pointer to the Morse code chacter bit pattern for
            // the chacater we want to send
            j++;
 
            // now get the bit pattern into bp
            bp = pgm_read_byte_near(morse_table + j);
 
            // start processing the bit pattern. ie: A = 00000101 = DOT DASH
            for (int i = 0; i < 8; i++)
            {
              // get the high bit of the pattern into our ditordah variable 
              /*
                  ie: 
                       00000101
                  AND  10000000 
                    =  00000000
               */
              ditordah = (bp & 128);
 
              // have we found our start flag yet ?
              if (first == false)
              {
                // if no, is it our start flag
                if (ditordah != 0)
                {
                  // yes - set our flag
                  first = true;
                }
 
                // now shift the bit pattern one bit to the left and continue
                bp = (bp << 1); //ie: 00000101 becomes 00001010
 
                /*
 
                  Continuing with the example A this will be shifted here until we reach
 
                  10100000
 
                  Then the first flag will be set. And the sequence 01 will be used below for the remainder of the loop
                 
                 */
                
                continue;
              }
 
              // if we've seen our start flag then send the dash or dot based on the bit
              if (ditordah != 0)
              {
                sendDash();
              }
              else
              {
                sendDot();
              }
 
              //we have a one unit delay between parts of the letter
              delay(ele_len);
  
              // now shift the bit pattern one bit to the left and continue
              
              bp = (bp << 1);//continue shifting bits in the sequence until complete
            }
 
            // there is a three element delay between chacaters.  the sendDash() or
            // sendDot() functions already add a one element delay so we delay
            // two more element times.
            delay(ele_len * 2);
            return;
          }
        }
 
        j++;
        j++;
      }
 
      break;
  }
}
Blink Morse Code with an Arduino
